Aminet 23/Aminet 23 (1998)(GTI - Schatztruhe)[!][Feb 1998].iso/Aminet/biz/dbase/McF51.lha/McFiler5.1/Install/Install_McF

Text File | 1997-11-30 | 6KB | 292 lines

; $VER: Install_McFiler 5.1 (27.11.97) by Alex Pagnoni & Roberto Bizzarri

;German strings

(procedure deutsch
    (
        (set badkick "\nMcFiler benötigt KickStart 3.0+!")
        (set selectdir "\nWo soll McFiler installiert werden ?\n(ANMERKUNG: Es wird ein Verzeichnis errichtet)")
        (set mkdir "\nEin Verzeichnis für McFiler wird errichtet")
        (set icons "\nMöchtest du MagicWB Piktogramme und Docks\nfür ToolManager installieren?")
        (set catlgs "\nWähle eine Sprache:\n(ANMERKUNG: Englisch ist die eingebaute)\n")
        (set prefs "\nS:McFiler.prefs existiert schon! Überschreiben?\n")
        (set conv "\nMöchtest du den `McF-Converter' installieren?\nDieses Tool konvertiert alte Datenbankdateien für die Version 5.0/5.1")
        (set mex "\nMcFiler 5.0 wurde installiert!")
    )
)

;Italian strings

(procedure italiano
    (
        (set badkick "\nMcFiler richiede il Kickstart 3.0+ per funzionare!")
        (set selectdir "\nScegli la directory in cui installare McFiler\n(NOTA: verrà creata una directory)")
        (set mkdir "\nVerrà creata la directory per McFiler")
        (set icons "\nVuoi copiare altre icone MagicWB\ne Dock per Tool Manager?")
        (set catlgs "\nScegli il linguaggio:\n(NOTA: l'inglese è il linguaggio di default)\n")
        (set prefs "\nS:McFiler.prefs esiste già! Sovrascrivo?\n\nNB: se prima si usava la v4.x è necessario sovrascrivere!\n")
        (set conv "\nVuoi copiare `McF-Converter'? Questo programma converte\ni vecchi file dati nella versione 5.0/5.1")
        (set mex "\nMcFiler 5.1 è stato installato!")
    )
)

;English strings

(procedure english
    (
        (set badkick "\nMcFiler requires KickStart 3.0+ to run!")
        (set selectdir "\nSelect the directory where install McFiler\n(NOTE: a directory will be created)")
        (set mkdir "\nA directory for McFiler will be created")
        (set icons "\nDo you want to copy more MagicWB icons\nand Docks to use with ToolManager?")
        (set catlgs "\nSelect a language:\n(NOTE: English is the built-in one)\n")
        (set prefs "\nS:McFiler.prefs already exists! Overwrite?\n\nNB: if you were using v4.x you must overwrite!\n")
        (set conv "\nDo you want to copy `McF-Converter'?\nThis tool converts old datafile to version 5.0/5.1")
        (set mex "\nMcFiler 5.1 has been installed!")
    )
)


;Main script

;Select installer language

(if (= @language "deutsch") (deutsch))
(if (= @language "italiano") (italiano))
(if (= @language "english") (english))

;Check os version

(set osversion (/ (getversion) 65536))

(if (< osversion 39) (abort badkick))

(welcome "McFiler 5.1 © 1994-1997 Roberto Bizzarri")

;Ask destination

(set @target-dir
    (askdir
        (help @askdir-help)
        (prompt selectdir)
        (default "Work:")
        (disk)
    )
)

(set @target-dir (tackon @target-dir "McFiler"))
(set @default-dest @target-dir)

(complete 0)

(makedir
    @target-dir
    (help)
    (prompt mkdir)
    (infos)
)

;Check CPU

(if (= "68000" (database "cpu"))
    (set mcfsource "/McFiler")
    (set mcfsource "/McFiler_020")
)

;Copy McFiler

(complete 10)
(copyfiles
    (prompt copymcf)
    (source mcfsource)
    (newname "McFiler")
    (dest @target-dir)
    (infos)
)

(complete 20)
(copyfiles
    (source "/McFiler_def.info")
    (dest @target-dir)
    (infos)
)

;Check if key is present and copies it

(complete 30)
(if (AND (exists "/McFiler.key") (NOT (exists "S:McFiler.key")))
    (copyfiles
        (source "/McFiler.key")
        (dest "S:")
    )
)

;Ask for icons

(complete 35)
(if
    (askbool
        (help @askchoice-help)
        (prompt icons)
        (default 0)
    )
    (
        (copyfiles
            (source "/MagicWB/")
            (all)
            (dest (tackon @target-dir "MagicWB"))
            (infos)
        )
        (copyfiles
            (source "/MagicWB.info")
            (dest @target-dir)
        )
    )
)

(complete 40)
(tooltype
    (dest (tackon @target-dir "McFiler_def"))
    (setdefaulttool (tackon @target-dir "McFiler"))
)

;Copy docs and catalogs

(complete 45)
(set catchoice
    (askchoice
        (prompt catlgs)
        (help @askchoice-help)
        (choices
            "English"
            "Italiano"
            "Deutsch"
        )
    )
)
(makedir (tackon @target-dir "Docs"))
(copyfiles
    (source "/Docs.info")
    (dest @target-dir)
)

(if (= catchoice 0)
    (
        (copyfiles
        (source (tackon "/docs" "McF5.1_eng.guide"))
        (prompt copy)
        (infos)
        (dest (tackon @target-dir "Docs"))
        )
    )
)

(complete 50)
(if (= catchoice 1)
    (
        (copyfiles
        (source (tackon "/docs" "McF5.1_ita.guide"))
        (prompt copy)
        (infos)
        (dest (tackon @target-dir "Docs"))
        )
        (makedir (tackon @target-dir "Catalogs"))
        (copyfiles
        (source "/Catalogs.info")
        (dest @target-dir)
        )
        (copyfiles
            (source "/catalogs/italiano/")
            (all)
            (dest (tackon @target-dir "catalogs/italiano"))
        )
    )
)

(complete 60)
(if (= catchoice 2)
    (
        (copyfiles
        (source (tackon "/docs" "McF5.1_deu.guide"))
        (prompt copy)
        (infos)
        (dest (tackon @target-dir "Docs"))
        )
        (makedir (tackon @target-dir "Catalogs"))
        (copyfiles
        (source "/Catalogs.info")
        (dest @target-dir)
        )
        (copyfiles
            (source "/catalogs/deutsch/")
            (all)
            (dest (tackon @target-dir "catalogs/deutsch"))
        )
    )
)


;Check if S:McFiler.prefs exists and ask for copy

(set overwrite 0)
(complete 70)
(if (exists "S:McFiler.prefs")
    (set overwrite
            (askbool
                (help @askchoice-help)
                (prompt prefs)
                (default 1)
            )
    )
)

(complete 80)
(if (= overwrite 1)
    (
        (if (= catchoice 0)
            (copyfiles
                (source "/McFiler.prefs")
                (dest "S:")
            )
        )
        (if (= catchoice 1)
            (copyfiles
                (source "/McFiler.prefs_ita")
                (newname "McFiler.prefs")
                (dest "S:")
            )
        )
        (if (= catchoice 2)
            (copyfiles
                (source "/McFiler.prefs_deu")
                (newname "McFiler.prefs")
                (dest "S:")
            )
        )
    )
)

;Copy for McF_Converter

(complete 90)
(if
    (askbool
        (help @askchoice-help)
        (prompt conv)
        (default 1)
    )
    (
        (copyfiles
            (source "/McF_Converter")
            (dest @target-dir)
            (infos)
        )
    )
)

;Installation done!

(complete 100)
(message mex)

;End of installer script